怎样用 Toolbar ActiveX 控件来生成 Coolbar 界面

概述

本文描述如何用 Microsoft Toolbar Version 6.0 ActiveX 控件创建一个类似于 Coolbar 的界面.

更多信息

Coolbar 界面是一种仅当用户移动动它上面才突起的的按钮, 就象 IE 4.0 那样.

主要的生成 Coolbar 按钮的属性是 Toolbar Active 控件的 Style 属性. Style 属性的默认值是 "0 [ASCII 150] Standard" 按钮. 改变该属性为 "1 [ASCII 150] Transparent" 可提供类似于 Coolbar 按饭的效果.

示例

用以下代码创建一个程序文件:
PUBLIC x
x=CREATEOBJECT("myform")
x.SHOW

**************************************************
* myform - Class Definition
**************************************************
DEFINE CLASS myform as Form
ADD OBJECT myclass1 AS myclass
ADD OBJECT check1 AS checkbox WITH;
Top = 150,;
Left = 50,;
Height = 50,;
Caption = "CoolBar"

PROCEDURE check1.Click
DO CASE
CASE This.value = 0
&& Changing the Toolbar to look like Coolbar.
Thisform.myclass1.OBJECT.Style = 0
CASE This.value = 1
&& Changeing the Toolbar to Standard Toolbar.
Thisform.myclass1.OBJECT.Style = 1
ENDCASE
ENDPROC

PROCEDURE myclass1.ButtonClick
*** ActiveX Control Event ***
LPARAMETERS button
DO CASE
CASE Button.key = "One"
WAIT WINDOW "Test1"
CASE Button.key = "Two"
WAIT WINDOW "Test2"
CASE Button.key = "Three"
WAIT WINDOW "Test3"
ENDCASE
ENDPROC

PROCEDURE myclass1.ButtonMenuClick
*** ActiveX Control Event ***
LPARAMETERS buttonmenu
DO CASE
CASE buttonmenu.key = "One"
WAIT WINDOW "SubOne"
CASE buttonmenu.key = "Two"
WAIT WINDOW "SubTwo"
ENDCASE
ENDPROC

ENDDEFINE

*-- EndDefine: myform
**************************************************

**************************************************
* myclass - Class Definition
**************************************************
DEFINE CLASS myclass AS olecontrol

#DEFINE tbrDEFAULT 0 && (默认) 按钮
#DEFINE tbrCHECK 1 && 复选框
#DEFINE tbrBUTTONGROUP 2 && 按钮组
#DEFINE tbrSEPARATOR 3 && 分隔器
#DEFINE tbrPLACEHOLDER 4 && 占位器
#DEFINE tbrDROPDOWN 5 && 菜单按钮下拉

Top = 0
Left = 0
Height = 38
Width = 375
Align = 1
Name = "Olecontrol1"
OleClass = "MSComCtlLib.Toolbar.2"

PROCEDURE Init
This.Buttons.Add(,"One","Test1",,)
This.Buttons.Add(,"Two","Test2",,)
This.Buttons.Add(,"Spr",,tbrSEPARATOR,)
This.Buttons.Add(,"Three","Test3",tbrDROPDOWN,)
This.Buttons(4).ButtonMenus.Add(1,"One","SubOne")
This.Buttons(4).ButtonMenus.Add(2,"Two","SubTwo")
ENDPROC

ENDDEFINE

*-- EndDefine: myclass
**************************************************