一、引言

Delphi除了能采用可视化方法进行编程和系统开发外，还有非常重要的一个功能，就是能用其语言本身开发Delphi的可视化控件（Component）。Delphi是完全面向对象的语言，其各个控件都是从最基本的类Tclass逐步继承而来，因此，编程者也可通过继承Delphi标准的控件类，开发出自己的控件，以满足某些特殊需要或使界面更为友好、美观。

在Windows 95的某些窗口中，用到了很多分隔线（如在资源管理器窗口中）。分隔线将一个窗口分成两个或多个部分。这些部分可能是面板（Panel）、图形、列表框或编辑区。当鼠标移到分隔线上时，光标会变成左右箭头或上下箭头，将鼠标按住并按指示的方向左右或上下拖动，就会使其中某部分放大，而另一部分缩小，从而提高了窗口各部分的可视范围，增加了窗口的信息量。
　

二、基本原理

分隔线界于窗口中两个控件之间。首先要在当前窗口中找到分隔线控件，并记录它的状态；然后要在窗口中找到与它相邻的控件，并记录它们的当前状态，然后再通过分隔线的鼠标事件控制各个控件的移动及尺寸变化，从而达到用分隔线分隔窗口的动态效果。
　

三、分隔线控件（Tsplit）对象

分隔线控件对象由现有的控件对象继承而来，在此基础上，还必须有它本身的私有变量（方法）和公有变量（方法）。具体为：

• 首先定义分隔线控件类：Tsplit。由于Delphi的面板控件Tpanel具有可改变其凸凹、形状大小等属性，所支持的事件方法也较多，因此采用Tpanel作为Tsplit的父类。
  　
• 定义Tsplit的私有变量和方法：与分隔线有关的一些控件，如其所在的窗口、分隔线本身、分隔线的坐标、分隔线在移动时使其大小改变的控件（主要指分隔线的左侧或上侧的控件，以下称目标）等，这些定义为私有变量；对分隔线和其周围控件的检测、画阴影线以及求其状态等过程（子程序），定义为私有方法。其中关键的变量有FSplitControl，FSizeTarget，它们为分隔线变量和所移动的目标控件变量，通过调用私有方法GetComponent可将它们赋值，得到分隔线和目标的实例，从而便于对他们操作。在分隔线移动时，DrawSizegLine方法画出它的阴影线。
  　
• 定义公共方法：公共方法定义了Tsplit的构造函数、开始移动分隔线、改变分隔
  线 的 位置、分隔线停止移动时调整目标（被分隔线改变形状的控件）尺寸等过程，以及分隔线的鼠标事件：按下、移动和弹起。另外，还定义了分隔线是否可移动的属性（property），以判断分隔线的当前状态。鼠标事件是分隔线移动和目标改变大小的触发点，对鼠标事件进行重载，使得移动和变化得以实现。在MouseDown事件中，加入了公共方法BeginSizing，对分隔线对象初始化；MouseMove事件中加入ChangeSizing方法，改变分隔线位置和画阴影；
  MouseUp事件中加入EndSizing，停止分隔线的移动，改变目标大小。
  　
• 分隔线控件实现过程 (见附录：split.pas程序及其说明。)
  　

四、控件的安装方法

在Delphi 1.0的系统菜单Options下(2.0为Components)，选择Install Component子菜单，弹出对话框，按Add按纽，在输入栏键入程序名及其路径，再按OK键，等待编译完毕，在Delphi的控件列表中的Sample栏中就会出现我们所开发的新控件：Split。
　

五、使用方法

• 建立一个新的项目文件（Project），在新窗口上放置一个面板（或列表框、树型结构列表、图形框、记忆框等），将其Align属性设为Left；
  　
• 从控件列表中的Sample栏中选取Split控件放于窗口，将其形状改为垂直的长条窄棒，并将Align属性设为Left，Cursor属性设为crHSplit；
  　
• 再在窗口中放一个面板（或其他控件），将其Align属性设为Client;
  　
• 运行该项目文件，当鼠标移动到分隔线上，且光标变为左右箭头时，即能将其两边的部分放大或缩小。
  若想做成上下分隔线，将以上1和2中的Align属性设为Top，2中的Cursor属性设为crVSplit，其余不变即可。

另外用户还可在3中的面板上再按1、2、3的步骤进行操作，将整个窗口用两个分隔线分为3个部分。以此类推，可将窗口分为任意多个部分。
本程序在Delphi 1.0和2.0下调试通过。

附录：源程序split.pas

unit Split;
interface
uses
SysUtils, WinTypes, WinProcs, Messages, Classes, Graphics, Controls,Forms,
Dialogs, ExtCtrls;
type {定义分隔线控件类}
Tspliter = class(Tpanel) {Tspliter类从Tpanel类继承}
private {定义私有变量和方法}
Fform: Tform; {分隔线所在的窗口变量}
FSplitControl, FSizeTarget: Tcontrol; {分隔线及要改变的目标控件变量}
Fvertical: Boolean; {分隔线方向变量}
Fsplit: Tpoint; {分隔线坐标变量}
FAOwner: Tcomponent; {分隔线的拥有者变量}
procedure GetComponents; {获得分隔线和目标实例}
function GetSizing: Boolean; {判断分隔线状态}
procedure DrawSizingLine; {画分隔线阴影}
public {定义公共方法}
constructor Create(Aowner: Tcomponent);override; {构造函数}
procedure BeginSizing; {移动前初始化}
procedure ChangeSizing(X, Y: Integer); {改变分隔线位置}
procedure EndSizing; {终止移动}
property Sizing: Boolean read GetSizing; {分隔线是否可移动属性}
procedure MouseDown(Button: TMouseButton; Shift: TShiftState; X, Y:Integer);
Override; {按下鼠标事件}
procedure MouseMove(Shift: TShiftState; X, Y: Integer);override; {移动鼠标事件}
procedure MouseUp(Button: TMouseButton; Shift: TShiftState; X, Y:
Integer);override; {弹起鼠标事件}
end;
procedure Register; {控件注册}
implementation
constructor Tspliter.Create(Aowner: Tcomponent);
begin
   inherited Create(Aowner);
   FAOwner := Aowner;
   Fform:= Tform(FAOwner); {定义分隔线所在的窗口类}
end;
function CToC(C1, C2: Tcontrol; P: Tpoint): Tpoint; {转换分隔线坐标函数}
begin
   Result := C1.ScreenToClient(C2.ClientToScreen(P));{将分隔线坐标转化为窗口坐标}
end;
   function Tspliter.GetSizing: Boolean;
begin
   Result := FSplitControl <> nil; {是否获得了分隔线变量}
end;
procedure Tspliter.DrawSizingLine;
var P: Tpoint;
begin
     P := CToC(Fform, FSplitControl, Fsplit);
     with Fform.Canvas do begin
     MoveTo(P.X, P.Y);
if Fvertical then {若为上下移动的分隔线，画横向阴影线}
LineTo(CToC(Fform, FSplitControl, Point(FSplitControl.Width, 0)).X, P.Y)
else {否则}
LineTo(P.X, CToC(Fform, FSplitControl, Point(0, FSplitControl.Height)
).Y) {画竖直的阴影线}
end;
end;
procedure Tspliter.BeginSizing;
begin
    GetComponents;
    SetCaptureControl(FSplitControl); {使分隔线可接受鼠标事件}
    if Fvertical then {获得分隔线的坐标}
       Fsplit := Point(0, FSplitControl.Top) else
       Fsplit := Point(FSplitControl.Left, 0);
      Fform.Canvas.Handle := GetDCEx(Fform.Handle, 0, DCX_CACHE or DCX_CLIPSIBLINGS
or DCX_LOCKWINDOWUPDATE); {取窗口句柄}
with Fform.Canvas do begin {设置画笔状态模式}
Pen.Color := clWhite;
if Fvertical then
   Pen.Width := FSplitControl.Height else
   Pen.Width := FSplitControl.Width;
   Pen.Mode := pmXOR;
end;
DrawSizingLine;
end;
procedure Tspliter.ChangeSizing(X, Y: Integer);
begin
    DrawSizingLine;
    if Fvertical then Fsplit.Y := Y else Fsplit.X := X; {移动分隔线位置}
      DrawSizingLine;
    end;
    procedure Tspliter.EndSizing;
var
DC: HDC;
P: Tpoint;
begin
  DrawSizingLine;
  P := CToC(FSizeTarget, FSplitControl, Fsplit); {将分隔线坐标转化为目标控件坐标}
  SetCaptureControl(nil); {将可接收鼠标事件的控件置空}
  FSplitControl := nil; {分隔线对象指向空}
  with Fform do begin
  DC := Canvas.Handle;
  Canvas.Handle := 0;
  ReleaseDC(Handle, DC); {释放窗口句柄}
end;
if Fvertical then begin {若为上下移动的分隔线}
if P.Y >= FSizeTarget.Parent.Height then Exit {若分隔线超过窗口高度退出}
else FSizeTarget.Height := P.Y; {否则改变目标高度}
end
else begin
if P.X >= FSizeTarget.Parent.Width then Exit {若分隔线超过窗口宽度退出}
else FSizeTarget.Width:= P.X; {否则改变目标宽度}
end;
end;
procedure Tspliter.MouseDown(Button: TMouseButton; Shift: TShiftState;
X, Y: Integer);
begin
inherited MouseDown(Button, Shift, X, Y); {继承原方法}
if (Button = mbLeft) and (Shift = [ssLeft]) then BeginSizing; {判断鼠标按键，开始移动}
end;
procedure Tspliter.MouseMove(Shift: TShiftState; X, Y: Integer);
begin
  inherited MouseMove(Shift, X, Y);
  if Sizing then ChangeSizing(X, Y);
end;
procedure Tspliter.MouseUp(Button: TMouseButton; Shift: TShiftState;X,Y: Integer);
begin
   inherited MouseUp(Button, Shift, X, Y);
   if Sizing then EndSizing; {若获得分隔线对象，结束移动}
end;
procedure Tspliter.GetComponents;
var I: Integer;
begin
   FSplitControl:= GetCaptureControl; {获得窗口中的分隔线对象}
   Fvertical := FSplitControl.Width > FSplitControl.Height;
   if not Fvertical then begin {若为横向分隔线}
      for I:= 0 to FSplitControl.Parent.ControlCount-1 do {在分隔线所在的控件上搜寻与它相邻的控件}
begin
if (FSplitControl <> FSplitControl.Parent.Controls[I]) and
   (FSplitControl.Left - FSplitControl.Parent.Controls[I].Width >= 0) and
   (FSplitControl.Left - FSplitControl.Parent.Controls[I].Width < 8) then
begin
   FSizeTarget:= Tcontrol(FSplitControl.Parent.Controls[I]); {获得目标控件}
     Break; {跳出循环}
     end
   end;
end
else begin {若为纵向分隔线}
for I:= 0 to FSplitControl.Parent.ControlCount-1 do begin
if (FSplitControl <> FSplitControl.Parent.Controls[I]) and
(FSplitControl.Top - FSplitControl.Parent.Controls[I].Height >= 0) and
(FSplitControl.Top - FSplitControl.Parent.Controls[I].Height < 8) then
    begin
     FSizeTarget:= Tcontrol(FSplitControl.Parent.Controls[I]);
     Break;
        end;
      end;
   end;
end;
procedure Register;
begin
   RegisterComponents('Samples', [Tspliter]);{将分隔线控件注册到Sample控件列表中}
end;
end.